建站
咨詢
售后
建站咨詢
新聞中心
這篇文章主要介紹了如何使用批處理重命名特殊文件名，具有一定借鑒價值，感興趣的朋友可以參考下，希望大家閱讀完這篇文章之后大有收獲，下面讓小編帶著大家一起了解一下。
一b!a!1235@_ s%#8i 三 c.rar
h^e12 0~%l%!p!@. s321-的文件.txt
%o%%% !O!ffi9~ ce$- Wor8d29 文檔.docx
重命名.bat
圖1：
要求運行批處理將這三個文件文件名中的數(shù)字、漢字、特殊字符全部(含空格)去掉，而重命名為只含字母的文件，但
后綴名不能更改，同時批處理自身名字不能更改，重命名后：
basic.rar
helps.txt
oOfficeWor.docx
重命名.bat
圖2：
要求：代碼簡潔、通用、效率不至于太低。
pusofalse：
代碼如下:
@echo off
for %%a in (*.*) do (
if "%%~nxa" neq "%~nx0" (
set "name=%%~na"
setlocal enabledelayedexpansion
set name1=!name!
call :lp
ren "!name!%%~xa" "!nam!%%~xa"
set "nam="
endlocal
)
)
pause
:lp
if defined name1 (
set "var=!name1:~,1!"
if "!var!" leq "Z" (
if "!var!" geq "a" (
set "nam=!nam!!var!"
))
set "name1=!name1:~1!"
goto lp
)
batman：
代碼如下:
@echo off
set "code=a b c d e f g h i j k l m n o p q r s t u v w x y z"
for /f "delims=" %%a in ('dir /s /a-d /b') do (
if "%%~nxa" neq "重命名.bat" (
set "str=%%~na"&set "file=%%a"&set "var=%%~na"
setlocal enabledelayedexpansion
for %%i in (%code%) do set "str=!str:%%i=!"
set "str=!str: =!"&call :lp
ren "!file!" !files!%%~xa
endlocal
))
goto :eof
:lp
set /a n+=1
for /f "tokens=%n% delims=%str% " %%a in ("%var%") do (
if "%%a" neq "" set "files=!files!%%a"&goto lp
)
描述下整體思路吧：
大家看到了題中的文件名是由字母+數(shù)字+特殊字符+漢字組成的，看起來很復雜，但我們是不是可以換個角度這樣看：文件名是由分隔符+字母組成的(將數(shù)字、特殊字符、漢字全看成分隔符)，是不是簡單多了，呵呵，麻煩的還在后面。。。
那么，我們又遇到問題了：數(shù)字、特殊字符還好說數(shù)量是有限的，漢字可是個麻煩事啊，我們總不能在delims=后面把所有漢字全寫上吧(況且這個長度是有限的)？這是不可能的，怎么辦呢？于是，我們可以先將文件名中不是字母的字符全提出來，怎么提？這就要用到變量替換了，將26個字母全替換為空。
有人會說了效率有問題，這里確實存在效率問題，但大家想一下比較逐字符的判斷的效率這個還是要高一點，為什么？假設一個文件名有十幾個a，用逐字符就要判斷十幾次，而變量替換只一次就搞定了。
經(jīng)過這樣替換后的字符串中是不是只留下了不是字母的字符?，F(xiàn)在只要把其來做為分隔符(別忘了加上空格)來提取文件名中的所有的字母了，而剩下的工作就只是技術(shù)處理了。
dishuo：
根據(jù) pusofalse斑竹的思路，提取字符最方便的工具肯定是正則表達式，批處理命令一個支持正則的就是findstr，能不能用它來提取呢？
測試成功！
滿足要求：簡潔、通用、效率不至于太低。
特點：通用性很強，只需要修改 findstr 的正則參數(shù)就能實現(xiàn)各種功能，舉幾個例子。
"[^-!-~0-9a-z]" 保留全角字符（中文、全角標點等）
"[a-z0-9]" 保留英文字母和數(shù)字
代碼如下:
@echo off&cls
for /f "tokens=*" %%i in ('dir /b/a-d "*.*"') do (
if "%%~nxsi" neq "%~nxs0" (
set "舊文件名=%%~nxsi"&set "文件名串=%%~ni"&set "新文件名="&set "counter=0"
del ~filenamechar.lst /q>nul 2>&1
setlocal enabledelayedexpansion
call :split
for /f "tokens=*" %%n in ('findstr "[a-z]" ~filenamechar.lst') do set "新文件名=!新文件名!%%n"
if "!新文件名!" neq "" (
echo ren !舊文件名! !新文件名!%%~xi
) else (
echo ^(文件"!舊文件名!"不含字母,不能重命名.^)
)
endlocal
)
)
del ~filenamechar.lst /q>nul 2>&1
pause&goto :eof
:split
if "!文件名串:~%counter%,1!" neq "" (
if "!文件名串:~%counter%,1!" neq " " echo !文件名串:~%counter%,1!>>~filenamechar.lst
set /a counter+=1
goto split
)
goto :eof
感謝你能夠認真閱讀完這篇文章，希望小編分享的“如何使用批處理重命名特殊文件名”這篇文章對大家有幫助，同時也希望大家多多支持創(chuàng)新互聯(lián)網(wǎng)站建設公司，，關注創(chuàng)新互聯(lián)行業(yè)資訊頻道，更多相關知識等著你來學習!
分享名稱：如何使用批處理重命名特殊文件名-創(chuàng)新互聯(lián)
本文網(wǎng)址：http://fisionsoft.com.cn/article/dcpiij.html
